Аналитика
http://www.geosystema.net/forum/

Импорт файлов DAT в Digitals в Формате (NXYZC).
http://www.geosystema.net/forum/viewtopic.php?f=1&t=3767
Страница 1 из 1

Автор:  Segga [ 05 мар 2014 11:09 ]
Заголовок сообщения:  Импорт файлов DAT в Digitals в Формате (NXYZC).

Помогите пожалуйста, есть ли возможность закинуть точки в Digitals, чтоб коди точек в файле DAT, или TxT присваивались например параметру "Шифр агрогрупи", или любому другому параметру?

Автор:  Dmitry_Zolotar [ 05 мар 2014 11:38 ]
Заголовок сообщения:  Re: Импорт файлов DAT в Digitals в Формате (NXYZC).

Segga писал(а):
Помогите пожалуйста, есть ли возможность закинуть точки в Digitals, чтоб коди точек в файле DAT, или TxT присваивались например параметру "Шифр агрогрупи", или любому другому параметру?

Вот скрипт:
Код:
;Импорт пикетов с кодами
$FN=@Dialog.OpenFile *.txt
$FE=@FileExists $FN
@if $FE=0 then @Break Файл $FN не найден
@Text[1].Load $FN
$CN=@Text[1].Count
@if $CN<1 then @Break Пустой файл
popTemplate | <Чистый>
$L=@Map.Layers.Add 75000 3 Пикет
$PN=@Map.Parameters.Add 7500001 3 Номер
$PC=@Map.Parameters.Add 7500001 5 Код
@Map.Layers.SetValidParameters $L -2 $PN $PC
$I=0
%Loop
$I=$I+1
@if $I>$CN then @Goto %Exit
$S=@Text[1].Line[$I]
$Number=@StringPart 1 $S
$X=@StringPart 2 $S
$Y=@StringPart 3 $S
$Z=@StringPart 4 $S
$Code=@StringPart 5 $S
$Obj=@Map.NewObject $L
@Map.Object[$Obj].Point[1] $X $Y $Z
@Map.Object[$Obj].Parameter[$PN] $Number
@Map.Object[$Obj].Parameter[$PC] $Code
@Goto %Loop
%Exit
Пометить | Все
Карта | Помеченные в рамку
Снять пометку | Все
Вид | Показать все

Автор:  Segga [ 05 мар 2014 12:01 ]
Заголовок сообщения:  Re: Импорт файлов DAT в Digitals в Формате (NXYZC).

не работает, вроде сбивает все в кучу, такое впечетление что не считывает координат. Напишите пожалуйста в каком формате должен быть TxT файл, и какой разделитель? Может по скрипту и можно понять что должно быть, но я просто в скриптах темный.....
Вот что у меня выходит:

Вложения:
555555.dmf [23.27 Кб]
Скачиваний: 612

Автор:  Dmitriy Fedorov [ 05 мар 2014 12:16 ]
Заголовок сообщения:  Re: Импорт файлов DAT в Digitals в Формате (NXYZC).

Segga писал(а):
Помогите пожалуйста, есть ли возможность закинуть точки в Digitals, чтоб коди точек в файле DAT, или TxT присваивались например параметру "Шифр агрогрупи", или любому другому параметру?

- Формат следующий:
Номер X Y Z Код (через пробел)
- В Сервис - Настройка -закладка Чтение - группа DAT введите код слоя, куда будут помещены точки и, через запятую, коды параметров для сохранения номера и кода.
Все, можно открывать.

Автор:  Dmitry_Zolotar [ 05 мар 2014 12:23 ]
Заголовок сообщения:  Re: Импорт файлов DAT в Digitals в Формате (NXYZC).

формат как в названии темы, а разделитель столбцов - пробел

изменил для табулятора-разделителя:
Код:
$Tab=@Calc char(9)
$Tab=@DequoteText $Tab
;Импорт пикетов с кодами
$FN=@Dialog.OpenFile *.txt
$FE=@FileExists $FN
@if $FE=0 then @Break Файл $FN не найден
@Text[1].Load $FN
$CN=@Text[1].Count
@if $CN<1 then @Break Пустой файл
popTemplate | <Чистый>
$L=@Map.Layers.Add 75000 3 Пикет
$PN=@Map.Parameters.Add 7500001 3 Номер
$PC=@Map.Parameters.Add 7500001 5 Код
@Map.Layers.SetValidParameters $L -2 $PN $PC
$I=0
%Loop
$I=$I+1
@if $I>$CN then @Goto %Exit
$S=@Text[1].Line[$I]
$Number=@StringPart 1$Tab$S
$X=@StringPart 2$Tab$S
$Y=@StringPart 3$Tab$S
$Z=@StringPart 4$Tab$S
$Code=@StringPart 5$Tab$S
$Obj=@Map.NewObject $L
@Map.Object[$Obj].Point[1] $X $Y $Z
@Map.Object[$Obj].Parameter[$PN] $Number
@Map.Object[$Obj].Parameter[$PC] $Code
@Goto %Loop
%Exit
Пометить | Все
Карта | Помеченные в рамку
Снять пометку | Все
Вид | Показать все

Автор:  Segga [ 05 мар 2014 16:11 ]
Заголовок сообщения:  Re: Импорт файлов DAT в Digitals в Формате (NXYZC).

Большое спасибо все вышло!!!!

Автор:  deadmansue [ 25 апр 2014 12:15 ]
Заголовок сообщения:  Re: Импорт файлов DAT в Digitals в Формате (NXYZC).

- В Сервис - Настройка -закладка Чтение - группа DAT введите код слоя, куда будут помещены точки и, через запятую, коды параметров для сохранения номера и кода.
Все, можно открывать.[/quote]

у меня не получилось, как это должно выглядеть? можно скриншот?

Страница 1 из 1 Часовой пояс: UTC + 2 часа
Powered by phpBB © 2000, 2002, 2005, 2007 phpBB Group
http://www.phpbb.com/