Без кодів, тільки з номером відкриваються dat-файли(NXYZ) на normal.dmf, в Сервис-Настройки-Чтение-DAT(NXYZ)/ASCII можна налаштувати код шару та код параметра для номера.
Якщо с кодами, то є скрипт для відкриття таких файлів:
Код:
;Импорт пикетов с кодами
$FN=@Dialog.OpenFile *.dat
$FE=@FileExists $FN
@if $FE=0 then @Break Файл $FN не найден
@Text[1].Load $FN
$CN=@Text[1].Count
@if $CN<1 then @Break Пустой файл
popTemplate | <Чистый>
$L=@Map.Layers.Add 75000 3 Пикет
$PN=@Map.Parameters.Add 7500001 3 Номер
$PC=@Map.Parameters.Add 7500001 5 Код
@Map.Layers.SetValidParameters $L -2 $PN $PC
$I=0
%Loop
$I=$I+1
@if $I>$CN then @Goto %Exit
$S=@Text[1].Line[$I]
$Number=@StringPart 1 $S
$X=@StringPart 2 $S
$Y=@StringPart 3 $S
$Z=@StringPart 4 $S
$Code=@StringPart 5 $S
$Obj=@Map.NewObject $L
@Map.Object[$Obj].Point[1] $X $Y $Z
@Map.Object[$Obj].Parameter[$PN] $Number
@Map.Object[$Obj].Parameter[$PC] $Code
@Goto %Loop
%Exit
Пометить | Все
Карта | Помеченные в рамку
Снять пометку | Все
Вид | Показать все
Можна модіфікувати скрипт, щоб завантажувався шаблон, автоматично визначався шар по коду і т.п.