Схожий скрипт зробив 2 дні тому. В буфер обміну копіюється табульований список(в ексель зручно вставляти) з кадномеру, назви власника, площі та назви виконавця робіт
Код:
@Text[1].Clear
$Tab=@Calc char(9)
$Tab=@DequoteText $Tab
$MC=@Map.Count
$I=0
%Loop
$I=$I+1
$LID=@Map.Object[$I].LayerID
@if $LID<>70005 then @Goto %Ignore
$ParcelNum=@Map.Object[$I].Parameter[ID7000513]
$CadZoneNum=@Map.Object[$I].CalculateFormula Parent[ID7000301](ID70003)
$CadQuarterNum=@Map.Object[$I].CalculateFormula Parent[ID7000401](ID70004)
$FullCadNum=@Concat $CadZoneNum,:,$CadQuarterNum,:,$ParcelNum
$Area=@Map.Object[$I].Parameter[ID7000516]
$Area=%Library.ReplaceComma $Area
$Executor=@Map.Object[$I].CalculateFormula Parent[ID7000007](ID70000)
$ExecutorNM=@XML.XPath CompanyName $Executor
$S=@Map.Object[$I].Parameter[ID7000520]
$PrCount=@XML.NodeCount /Proprietors ProprietorInfo $S
$Res=
@if $PrCount<1 then @Goto %IgnoreProp
$J=0
%LoopProp
$J=$J+1
@if $J>1 then $Res=$Res|
$IsLE=@XML.NodeCount /Proprietors/ProprietorInfo[$J]/Authentication LegalEntity $S
@if $IsLE=1 then @Goto %LE
$LN=@XML.XPath /Proprietors/ProprietorInfo[$J]/Authentication/NaturalPerson/FullName/LastName $S
$FN=@XML.XPath /Proprietors/ProprietorInfo[$J]/Authentication/NaturalPerson/FullName/FirstName $S
$MN=@XML.XPath /Proprietors/ProprietorInfo[$J]/Authentication/NaturalPerson/FullName/MiddleName $S
$Res=$Res$LN $FN $MN
@Goto %NextProp
%LE
$LEName=@XML.XPath /Proprietors/ProprietorInfo[$J]/Authentication/LegalEntity/Name $S
$Res=$Res$LEName
%NextProp
@if $J<$PrCount then @Goto %LoopProp
$ResS=@Concat $FullCadNum,$Tab,$Res,$Tab,$Area,$Tab,$ExecutorNM
@Text[1].Add $ResS
%Ignore
@if $I<$MC then @Goto %Loop
@Text[1].Copy